home *** CD-ROM | disk | FTP | other *** search
/ Magnum One / Magnum One (Mid-American Digital) (Disc Manufacturing).iso / d11 / basmus.arc / DANCE.BAS (.txt) < prev    next >
Encoding:
GW-BASIC  |  1990-09-29  |  3.0 KB  |  57 lines
  1. 1  ' ANITRA = Music          from  P. Fraundorf         2/83
  2. 10     ' anitra.bas: Anitra's Dance from "Peer Gynt" by Edvard Grieg
  3. 11      ' adapted for the IBM PC; (c) P. Fraundorf 1982
  4. 15  CLS:LOCATE 12,30:PRINT "A N I T R A ' S   D A N C E":PRINT:PRINT:PRINT
  5. 20     ' ----------------------define manuscript phrases----------------------
  6. 30       A$="MLO5e2. e4p2 MSO1a4O3c4dd O1a4O3e4ff O1a4O3e4dd O1a4O3c4"
  7. 40       B1$="O3e4 MLa64b64a16.MSg#abO4cd MLeae4Xtd$; cac4O3Xtb$; MNa2p4"
  8. 50       B2$="MLaO4cO3a4Xtg$; f#O4cO3MNf#2 MLfO4cO3f4Xte$; d#bMNd#2"
  9. 60       B3$="MSba#f#baf bg#ebgd# bf#dbfc# becbd#O2b"
  10. 70       B4$="MLO3e64f#64e16.MSd#ef#ga bO4eO3bagf# ef#gab4 O4e4p4"
  11. 80       B$=B1$+B2$+B3$+B4$
  12. 90       C1$="MLf4.MNeMLeMNd MLd4.MNeMLeMNf f2. MSe4p2 p8O3fdcO2bMLO3f"
  13. 100      C2$="MSdcO2bO3dO2ba g#MLO3dMSO2bag#b g#fedcO1b"
  14. 110      C3$="O4MLb-4.MNaMLaMNg MLg4.MNaMLaMNb- b-2. MSa4p2 p8O3b-gfeMLb-"
  15. 120      C4$="MSgfeged c#MLgMSedc#e c#O2b-agfe"
  16. 130      C$=C1$+C2$+C3$+C4$
  17. 140      D1$="MSO2d4O3f#4g4 O2d4O3a4b4 O2d4O3a4a4 O4d64e64d16.c#def#g"
  18. 150      D2$="MLaO5dO4a4Xtg$; f#O5dO4f#4Xte$; MNd2."
  19. 160      D3$="MSO2d4O3f4g4 O2d4O3a4b-4 O2d4O3a4a4 O4d64e64d16.c#defg"
  20. 170      D4$="MLaO5dO4a4Xtg$; fO5dO4f4Xte$; MNd2."
  21. 180      D$=D1$+D2$+D3$+D4$
  22. 190      E1$="MSO1d-O2e-aO3cfO4c MLf64g64f16.MSefgab- MLO5cfcMSO3gab-"
  23. 200      E2$="MLO4cfc2 MSO1fO2f#aO3ceO4e MLa64b64a16.MSg#abO5cd"
  24. 210      E3$="MLeaeMSO3bO4cd MLeae2 MSO1bO2bO3d#f#ab MLO4f#64g64f#16.MSff#gab"
  25. 220      E$=E1$+E2$+E3$
  26. 230      F1$="MLO5cO4cf#MSO3g#ab MLO4cO3cf#2 MSO1eO2eg#bO3de"
  27. 240      F2$="T=T2; MLb64O4c64O3b16.MSa#bO4cde"
  28. 250      F3$="T=T3; MLfO3fbMScde T=T4; MLfO2fb4MNO3e4"
  29. 260      F$=F1$+F2$+F3$
  30. 270      G1$="T=T1; MLa64b64a16.MSg#abO4cd MLeae4Xtd$; cec4O3Xtb$; MNa2."
  31. 280      G2$="MLO4aO5cO4a4Xtg$; f#O5cO4f#2 fO5cO4f4Xte$; d#bd#2 dfd4Xtc$;"
  32. 290      G3$="O3bO4fO3b2 b-O4fo3b-4Xta$; g#O4eO3g#2 MSO4ed#O3bO4edO3b-"
  33. 300      G4$="O4ec#O3aO4ecO3g# O4eO3bgO4eO3a#f# O4eO3afO4eO3g#e
  34. 310      G$=G1$+G2$+G3$+G4$
  35. 320      H$="MLa64b64a16.MSg#abO4cd eaedcO3b abO4cde4 a4p4"
  36. 330    ' -------------------define qtr-note trill substrings------------------
  37. 340      TA$="a16b32a32b32a32b32a32"
  38. 350      TB$="b16O4c32O3b32O4c32O3b32O4c32O3b32"
  39. 360      TC$="c16d32c32d32c32d32c32"
  40. 370      TD$="d16e32d32e32d32e32d32"
  41. 380      TE$="e16f32e32f32e32f32e32"
  42. 390      TG$="g16a32g32a32g32a32g32"
  43. 400    ' ----------------------------determine tempo--------------------------
  44. 410      INPUT "tempo (80-255 qtr notes/min, rtn=160)";T1: IF T1=0 THEN T1=160
  45. 420      T2=0.8*T1: T3=0.6*T1: T4=0.4*T1
  46. 430    ' ----------------------------play the dance---------------------------
  47. 440      I$="p4": PLAY "T=T1; L8": PLAY A$: PLAY B$: PLAY B$+"p4"
  48. 450      FOR I=1 TO 2
  49. 460              PLAY C$: PLAY D$: PLAY E$: PLAY F$: PLAY G$: PLAY H$: PLAY I$
  50. 470              I$="O1E4 O0A4P2 MLO4A2. A4"
  51. 480              NEXT
  52. 490      PRINT " Play it again? (Y/N) ";:ANS$=INPUT$(1)
  53. 491      IF ANS$="Y" OR ANS$="y" THEN GOTO 410 ELSE GOTO 65000
  54. 65000  ' Return to Magazette
  55. 65001  LOCATE 24,1:PRINT SPACE$(79);:LOCATE 24,1:PRINT "  Press ESC key to continue ";:ANS$=INPUT$(1):IF ASC(ANS$)<>27 THEN 65001
  56. 65005  END
  57.